home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (PO) / Nibble Volume 09, No. 06 (1988-06)(MicroSPARC)(Side A).zip / Nibble Volume 09, No. 06 (1988-06)(MicroSPARC)(Side A).po / UNDIM.S < prev   
Text File  |  1996-12-24  |  2KB  |  66 lines
  1.                   TTL ""
  2. *********************
  3. *       UNDIM       *
  4. * BY BRIAN LONERGAN *
  5. * COPYRIGHT(C) 1988 *
  6. *  MICROSPARC, INC. *
  7. * CONCORD, MA 01742 *
  8. *LISA V2.5 ASSEMBLER*
  9. *********************
  10.                          ;
  11.                   ORG $300
  12.                          ;
  13. TOP            EPZ $6
  14. BYTES        EPZ $8
  15.                          ;
  16. PNTR          EPZ $9B
  17. ENDARRAY  EPZ $6D
  18.                          ;
  19. SYNCHR      =   $DEC0
  20. GETARYPT  =   $F7D9
  21.                          ;
  22.                          ;
  23. START        LDA '"
  24.                   JSR SYNCHR          ;VERIFY QUOTATION MARK
  25.                   JSR GETARYPT        ;PUT TABLE ADDRESS IN PNTR
  26.                   LDA '"
  27.                   JSR SYNCHR          ;VERIFY SECOND QUOTE
  28.                   LDY #$2             ;OFFSET TO TABLE LENGTH
  29.                   LDA (PNTR),Y        ;GET TABLE LENGTH
  30.                   STA BYTES           ; AND STORE IN BYTES
  31.                   INY 
  32.                   LDA (PNTR),Y
  33.                   STA BYTES+1
  34.                   CLC 
  35.                   LDA PNTR            ;PUT TOP OF ARRAY
  36.                   ADC BYTES           ; TABLE IN TOP
  37.                   STA TOP
  38.                   LDA PNTR+1
  39.                   ADC BYTES+1
  40.                   STA TOP+1
  41.                   SEC 
  42.                   LDA ENDARRAY        ;SUBTRACT TABLE LENGTH
  43.                   SBC BYTES           ; FROM THE END OF ARRAY
  44.                   STA ENDARRAY        ; TABLE PNTR
  45.                   LDA ENDARRAY+1
  46.                   SBC BYTES+1
  47.                   STA ENDARRAY+1
  48.                   LDY #$0
  49.                   BEQ DONEYET
  50. LOOP          LDA (TOP),Y
  51.                   STA (PNTR),Y
  52.                   INC TOP
  53.                   BNE INCPNTR
  54.                   INC TOP+1
  55. INCPNTR    INC PNTR
  56.                   BNE DONEYET
  57.                   INC PNTR+1
  58. DONEYET    LDA PNTR            ;IF ALL TABLES HAVE NOT
  59.                   CMP ENDARRAY        ; BEEN MOVED THEN
  60.                   BNE LOOP            ; LOOP TO LOOP
  61.                   LDA PNTR+1
  62.                   CMP ENDARRAY+1
  63.                   BNE LOOP
  64.                   RTS                 ;ALL DONE, BACK TO BASIC
  65.                   END 
  66.